With SAS® 9.2, titles and footnotes that are unique to individual graphs and individual regions are no longer associated with the individual graph and region when using ODS LAYOUT. While it is possible to display titles and footnotes that are common to the entire page with SAS 9.2, these titles and footnotes no longer display in the individual region with their respective graph.

If your SAS code contains multiple TITLE and FOOTNOTE statements, this might cause some titles and footnotes to be missing altogether.

With SAS/GRAPH output, one way to circumvent the problem is to replace the missing titles and footnotes with one or more NOTE statements, using the MOVE= option on the NOTE statement to place it on the appropriate position on the page. Another circumvention when producing graphics output is to use the Annotate facility to annotate titles and footnotes onto the graph. When using these circumventions, you might need to include the LENGTH= option in an AXIS statement for the vertical axis to force extra space at the top of the graph for these new titles.

The Full Code tab contains sample code which demonstrates how to add a title to SAS/GRAPH output when using ODS LAYOUT.

Note that ODS LAYOUT is experimental with both SAS 9.1 and SAS 9.2.

Operating System and Release Information

Product Family	Product	System	SAS Release
			Reported	Fixed*
SAS System	Base SAS	z/OS	9.2 TS1M0	9.2 TS2M3
		Microsoft® Windows® for 64-Bit Itanium-based Systems	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows Server 2003 Datacenter 64-bit Edition	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows Server 2003 Enterprise 64-bit Edition	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows XP 64-bit Edition	9.2 TS1M0	9.2 TS2M3
		Microsoft® Windows® for x64	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows Server 2003 Datacenter Edition	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows Server 2003 Enterprise Edition	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows Server 2003 Standard Edition	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows Server 2008	9.2 TS1M0	9.2 TS2M3
		Microsoft Windows XP Professional	9.2 TS1M0	9.2 TS2M3
		Windows Vista	9.2 TS1M0	9.2 TS2M3
		64-bit Enabled AIX	9.2 TS1M0	9.2 TS2M3
		64-bit Enabled HP-UX	9.2 TS1M0	9.2 TS2M3
		64-bit Enabled Solaris	9.2 TS1M0	9.2 TS2M3
		HP-UX IPF	9.2 TS1M0	9.2 TS2M3
		Linux	9.2 TS1M0	9.2 TS2M3
		Linux for x64	9.2 TS1M0	9.2 TS2M3
		OpenVMS on HP Integrity	9.2 TS1M0	9.2 TS2M3
		Solaris for x64	9.2 TS1M0	9.2 TS2M3

* For software releases that are not yet generally available, the Fixed Release is the software release in which the problem is planned to be fixed.

This sample code demonstrates two methods for adding a title to SAS/GRAPH output when using ODS LAYOUT. The first method uses the Annotate facility, while the second method uses a NOTE statement with the MOVE= option instead of a TITLE statement.

---

/* This sample code demonstrates how to use the */
/* SAS/GRAPH Annotate facility to add a TITLE   */
/* to PROC GCHART output when using ODS LAYOUT. */

data annods;
   length function color $ 8 text $ 30;
   retain function 'label' color 'black' when 'A' style '"Helvetica"'
          xsys '3' ysys '3' position '5' size 2;
   X = 50;
   Y = 98;
   text='This is my Graph Title';
run;

options nodate nonumber; 

goptions reset=all device=sasprtc target=sasprtc 
         ftext='helvetica' ftitle='helvetica' border; 

ods listing close; 
ods pdf file="c:\temp\sastest1.pdf" notoc;

ods layout start;  

ods region width=50 pct height=60 pct x=0 pct y=10 pct;

axis1 length=70 pct;  

proc gchart data=sashelp.class anno=annods; 
   vbar age / discrete raxis=axis1; 
run;
quit;

ods layout end;
ods pdf close; 
ods listing; 


/* This sample code demonstrates how to use a  */
/* NOTE statement with the MOVE= option to add */
/* a TITLE to PROC GCHART output when using    */
/* ODS LAYOUT.                                 */

goptions reset=all device=sasprtc target=sasprtc 
         ftext='helvetica' ftitle='helvetica' border; 

ods listing close; 
ods pdf file="c:\temp\sastest2.pdf" notoc;

ods layout start;  

ods region width=50 pct height=60 pct x=0 pct y=10 pct;

axis1 length=70 pct;  

proc gchart data=sashelp.class; 
   vbar age / discrete raxis=axis1; 
   note move=(18 pct, 95 pct) H=2 "This is my Graph Title";  
run;
quit;

ods layout end;
ods pdf close; 
ods listing; 

Titles and footnotes are no longer associated with individual graphs and individual regions when using ODS LAYOUT.

Type:	Problem Note
Priority:	medium

Date Modified:	2009-09-15 13:13:16
Date Created:	2009-09-02 13:10:15